A evolução dos CPU’s deixou, nos últimos anos, de estar relacionada com a velocidade do CPU, mas sim com o número de núcleos que este tem. Estes núcleos (cores) permitem executar diversos processos em simultâneo, melhorando a utilização e performance das aplicações, sendo para isso necessário que elas estejam desenhadas e preparadas para o fazer.
O Visual Studio 2010 e a .NET Framework 4.0 trazem um conjunto de melhorias com o objectivo de tirar partido do hardware, nomeadamente melhorias no namespace System.Theading, a introdução das Parallel Extensions, que são um conjunto de classes que permitem implementar a programação de tarefas em paralelo e a Unified Cancellation Model, que é, de uma forma sucinta, uma simplificação do processo de cancelamento de diversas threads usando um só comando.
São também novidade duas ferramentas de diagnóstico: Parallel Stacks Window e Parallel Tasks Window.
Sobre as Parallel Extensions, as principais novidades são:
O Visual Studio 2010 e a plataforma .NET Framework 4.0 vêm assim melhorar e simplificar o o processo de criação de threads, substituindo de certa forma, com as Parallel Extensions, a classe System.Theading.Thead (embora possível de utilizar).
O Visual Studio 2010 introduz suporte para utilização de objectos de linguagens dinâmicas, como IronPython ou IronRuby, e a criação de objecto dinâmicos, dentro da própria linguagem (VB ou C#). Isto torna possível a inclusão de métodos dinâmicos em linguagens estáticas, como são o VB.NET ou C#, através da Dynamic Language Runtime (DLR).
No caso do Visual Basic, isto permite outra forma, que não usando o tipo Object, de se ligar a objecto dinâmicos em latebind, ou seja, sem que o compilador tente interpretar o código e dê erro, sendo o código interpretado em modo de execução(run-time). Mais informação e vantagens sobre ambos os métodos: Early and Late Binding
Desta forma podemos em alguns casos, com a devida manipulação é claro, utilizar um sintaxe mais agradável, ou seja, não fazer:
Dim reader As SqlClient.SqlDataReader = command.ExecuteReader()
Me.txtNome.Text = reader.Item("nome")
Me.txtMorada.Text = reader.Item("morada")
Me.txtTelefone.Text = reader.Item("telefone")
Mas sim algo mais simples (uma vez que em ambos os casos não temos intellisense):
Dim reader As Object = New DynamicCommand(command)
Me.txtNome.Text = reader.nome
Me.txtMorada.Text = reader.morada
Me.txtTelefone.Text = reader.telefone
Isto consegue-se utilizando a classe DynamicObject(), do namespace System.Dynamic, permitindo a criação de objectos dinâmicos. De uma forma geral, podemos criar uma nova classe, que herda as propriedades e métodos do DynamicObject(), e através dos métodos TryGetMember() e TrySetMember() podemos identificar se estamos a definir uma propriedade ou a verificar o valor de uma propriedade. Existem mais métodos disponíveis, mas para o seguinte exemplo, iremos apenas utilizar estes dois.
Este pequeno exemplo irá guardar uma propriedade e depois verificar o seu valor. Bastante simples apenas para se entender o funcionamento geral.
Definição da classe dinâmica:
Public Class DynamicObjectTest
Inherits DynamicObject
Private m_dictionary As New Dictionary(Of String, Object)
''' <summary>
''' Verifica no Dictionary o valor guardado
''' </summary>
''' <returns></returns>
''' <remarks></remarks>
Public Overrides Function TryGetMember(
ByVal binder As GetMemberBinder,
ByRef result As Object) As Boolean
result = m_dictionary.Item(binder.Name.ToLower)
Return True
End Function
''' <summary>
''' Adiciona o nome e o valor no Dictionary
''' </summary>
''' <returns></returns>
''' <remarks></remarks>
Public Overrides Function TrySetMember(
ByVal binder As System.Dynamic.SetMemberBinder,
ByVal value As Object) As Boolean
m_dictionary.Add(binder.Name.ToLower, value)
Return True
End Function
End Class
Depois, criando uma nova instância e adicionado alguns valores:
' Cria uma nova instância da classe DynamicObjectTest
Dim myDynamicObject As Object = New DynamicObjectTest()
' Adiciona uma nova label (com algumas definições)
myDynamicObject.CustomObject = New Label() With
{
.Text = "Teste",
.Name = "lblTeste",
.Location = New Point(10, 10)
}
' Adiciona uma mensagem
myDynamicObject.Msg = "Dynamic Object Test"
Finalmente, a verificação e utilização dos valores guardados:
' Adiciona ao Form a label
Me.Controls.Add(myDynamicObject.CustomObject)
' Define como texto do Form a mensagem guardada
Me.Text = myDynamicObject.Msg
Uma funcionalidade que promete, que para além de permitir utilizar linguagens dinâmicas no VB.NET ou no C#, o que poderá trazer grandes vantagens, permite ainda criar objectos dinâmicos que podem ser utilizados na própria linguagem (onde aqui poderá ter menos utilização), ou mesmo em linguagens externas (desde que tenham suporte DLR)
Um artigo anterior, publicado neste blog, foi dedicado a Lambda Expressions, explicando de um modo geral o seu funcionamento e o seu sintaxe.
Com a chegada do Visual Studio 2010, algumas das limitações que existiam e que já estavam disponível no C# 3.0, foram introduzidas, já sendo agora possível criar expressões em múltiplas linhas e expressões que não retornam resultados.
Podemos então criar lambda expressions em uma linha ou em várias linhas:
' Função single-line
Dim result1 = Function(x) x * x
' Função multi-line
Dim result2 = Function(x)
Return (x * x)
End Function
' Mostra os resultados
Debug.WriteLine(result1(5))
Debug.WriteLine(result2(5))
E podemos também criar lambda expressions que não retornam resultados, substituindo a keyword Function() por Sub():
' Subrotina single-line
Dim showResult1 = Sub(result As Integer) Debug.WriteLine(result.ToString())
' Subrotina multi-line
Dim showResult2 = Sub(result As Integer)
Debug.WriteLine(result.ToString())
End Sub
' Mostrando os resultados
showResult1(12345)
showResult2(12345)
Mais alguns exemplos, um pouco mais complexos, de como podemos criar expressões em várias linhas, com diferentes validações e retornando ou não resultados:
Dim listValues As New List(Of Integer) From
{1, 2, 3, 4, 5, 6, 7, 8}
' Irá mostrar os resultados com diferentes outputs para
' os números superiores, inferiores e iguais a 5
Array.ForEach(listValues.ToArray,
Sub(x)
If x > 5 Then
Debug.WriteLine(x.ToString & " é maior que 5")
ElseIf x = 5 Then
Debug.WriteLine(x.ToString & " é o número certo")
Else
Debug.WriteLine(x.ToString & " é menor que 5")
End If
End Sub)
' Irá mostrar os resultados e irá colocar na variável 'result', todos os
' números superiores a 5, ou seja, criará um array com os número 6, 7 e 8
Dim result = Array.FindAll(listValues.ToArray,
Function(x)
Debug.WriteLine(x)
Return x > 5
End Function)
Mais algumas melhorias que vêm ajudar a tornar as lambda expressions mais versáteis e com cada vez com mais aplicação!
.png)
