Visual Basic em Português

O Microsoft Excel não é uma base de dados mas sim, como todos sabem, uma folha de cálculo. No entanto, e por ser bastante versátil e simples de trabalhar, há quem o utilize para tal. Não é aconselhável, pois existem outras formas de gerir dados, mas quando se trata de pouca informação e/ou informação que utilize muitos cálculos e gráficos, então porque não?

Para mostrar como criar uma gestão de dados em Excel, este artigo irá mostrar a criação de uma lista de contactos. É um exemplo simples, que será dividido em alguns artigos, irá mostrar a criação de um formulário para inserção de novos contactos. Nos próximos artigos deste exemplo, será mostrado como criar listagens, modificar dados, personalizar a folha, etc.

Neste artigo inicial podem-se ver alguns pontos de interesse: criação de funções, criação de sub rotinas ou rotinas auxiliares, ciclo nos controlos do userform, validação de dados, etc.

Para seja mais fácil a análise do código e como está a funcionar, será adicionado um exemplo no final do artigo.

Nesta folha de cálculo existem duas Worksheets: Principal e Registos. A Principal é onde serão colocado os botões de comando (para chamar os userforms), e a Registos onde serão guardados os dados. Foi ainda inserido um Userform. No userform, onde está o código principal, o código utilizado é o seguinte:

Option Explicit

' Função que verifica se o campo é válido e retorna o resultado da validação
Private Function ValidaContacto(ByVal Contacto As String, ByVal NomeCampo As String) As Boolean

    ' Verifica se o número de caracteres é diferente de 9 e não está vazio
    If Len(Contacto) <> 9 And Len(Contacto) <> 0 Then
        MsgBox "O campo " & NomeCampo & " não é válido.", vbExclamation
        ValidaContacto = False
        Exit Function
    End If

    ' Verifica se o campo é numérico e não está vazio
    If Not IsNumeric(Contacto) And Len(Contacto) <> 0 Then
        MsgBox "O campo " & NomeCampo & " não é numérico.", vbExclamation
        ValidaContacto = False
        Exit Function
    End If

    ' Caso não existam erros a função retorna um valor verdadeiro
    ValidaContacto = True

End Function

         

' Subrotina que limpa o formulário
Sub LimpaFormulario()
    Dim c As Control

    ' Faz um ciclo em todos os controls
    For Each c In Me.Controls

        ' Se o controlo for um TextBox
        ' limpa o texto do controlo
        If TypeOf c Is MSForms.TextBox Then
            c.Text = ""
        End If

    Next

    ' Coloca seleccionada a primeira opção
    OptionButton1.Value = True
    OptionButton2.Value = False
    OptionButton3.Value = False         

End Sub

         

' Insere o registo
Private Sub btnInserir_Click()

    ' Verifica se o campo nome está preenchido. Como este campo é de
    ‘ preenchimento obrigatório, não será utilizada a função ValidaContacto()
    If Len(txtNome.Text) = 0 Then
        MsgBox "O campo NOME é de preenchimento obrigatório.", vbExclamation
        Exit Sub
    End If

    ' Valida todos os campos. Como estes campos têm validações
    ' comuns (numérico e nove dígitos) foi criada uma função
    ' auxiliar de modo a reduzir e optimizar o código.
    If Not ValidaContacto(txtTelefone.Text, "TELEFONE") Then Exit Sub
    If Not ValidaContacto(txtTelemovel.Text, "TELEMÓVEL") Then Exit Sub
    If Not ValidaContacto(txtTrabalho.Text, "TELF. TRABALHO") Then Exit Sub
    If Not ValidaContacto(txtFax.Text, "FAX") Then Exit Sub

    ' Confirma se utilizador quer mesmo inserir o registo
    If MsgBox("Deseja inserir este registo ?", vbQuestion + vbYesNo + vbDefaultButton2) = vbYes Then

        Dim strGrupo As String
        Dim ultimaLinha As Long
        Dim ws As Worksheet

        Set ws = Worksheets("Registos")

        ' Verifica qual a ultima linha preenchida
        ultimaLinha = ws.Cells(65536, 1).End(xlUp).Row + 1

        ' Preenche as células
        ws.Cells(ultimaLinha, 1).Value = txtNome.Text

        ' Verifica qual a opção seleccionada
        If OptionButton1.Value Then
            strGrupo = "Familia"
        ElseIf OptionButton2.Value Then
            strGrupo = "Amigos"
        ElseIf OptionButton3.Value Then
            strGrupo = "Trabalho"
        End If

        ws.Cells(ultimaLinha, 2).Value = strGrupo
        ws.Cells(ultimaLinha, 3).Value = txtTelefone.Text
        ws.Cells(ultimaLinha, 4).Value = txtTelemovel.Text
        ws.Cells(ultimaLinha, 5).Value = txtTrabalho.Text
        ws.Cells(ultimaLinha, 6).Value = txtFax.Text
        ws.Cells(ultimaLinha, 7).Value = txtObs.Text

        ' Limpa o formulário
        Call LimpaFormulario()

        ' Coloca o cursor no campo Nome, para ficar pronto
        ' para a inserção de novos contactos
        txtNome.SetFocus

    End If

End Sub         

' Fechar o formulário
Private Sub btnFechar_Click()
    Unload Me
End Sub

' Limpar o formulário
Private Sub btnLimpar_Click()
    Call LimpaFormulario()
End Sub 

Este exemplo utiliza algum código mas poderá ser ainda mais complexo. Poderá, por exemplo, ser validado no campo telemóvel se inicia por 91,93 ou 96, obrigar o preenchimento de mais campos, obrigar a um número mínimo de caracteres, etc. O objectivo é no entanto mostrar como funciona e a implementação de alguns conceitos gerais.

Exemplo do artigo: DOWNLOAD DO FICHEIRO

PS: Como sempre, qualquer dúvida, comentário ou correcção ao artigo é sempre bem vinda!